网页功能: 加入收藏 设为首页 网站搜索  
让你的文本框“聪明”一点
发表日期:2003-12-26作者:mmcgzs (毛毛虫)[] 出处:  

近来在设计一个热键设置程序中我学会了使用Setwindowlong和Callwindowproc这两个Api函数,有了它我们就可以处理你的窗口或控件所接收到的任何消息.由于前一段时间我看过一篇介绍QQ密码监视盗取法的文章,使我想到是不是可以用这两个函数来进行密码保护呢,经过一番尝试终于成功了,现在拿出来与大家分享。

  几乎所有的监视程序都是通过向你密码的文本框发送一条WM_GETTEXT消息来获取密码的,任何文本框只要接收到此消息它就会老老实实的把自己保存的内容告诉发送消息者(它可不知道它保存的是我们重要的密码呀), “*”号是不能保护我们的密码的,是不是可以做一个“聪明”一点的文本框呢,其实我们只需拦截此消息不让文本框接受到,任何监视程序也不能得到其中的密码。就是用Setwindowlong和Callwindowproc这两个Api函数来定义一个自己的消息处理函数,然后判断消息类型,如果是WM_GetText消息就排除在外,不处理它(当然了你也可以更换接受消息的对象来欺骗它),这样文本框接收不到这条消息当然就不会泄露秘密了。下面对只作一个简单的介绍:

Setwindowlong函数声明如下:

   Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long

作用:在窗口结构中为指定的窗口设置信息

参数: hwnd 要设置消息函数的窗口句柄(可以是控件)

   nIndex 我们用到的是:GWL_WNDPROC 设置窗口或控件的消息处理函数的地址 

   dwNewLong 消息函数的地址(就是在函数名前加Addressof,如 addressof winproc)

返回值:如果成功返回原来消息处理函数的地址,否则返回0

 Callwindowproc函数声明如下:

   Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

参数: lpPrevWndFunc:指向前一个窗口或控件过程的指针。

  hWnd:指向接收消息的窗口或控件过程的句柄。

  Msg:指定消息类型。

  wParam:指定其余的、消息特定的信息。该参数的内容与Msg参数值有关。

IParam:指定其余的、消息特定的信息。该参数的内容与Msg参数值有关。

返回值:指定了消息处理结果,它与发送的消息有关。

了解了这两个函数我们就可以做一个“聪明”一点的文本框了:

1. 首先打开VB 建立一个工程,添加一个窗体,一个模块

2.  将上面的两个函数的声明加入模块中,再加上两个变量的声明就是

   Public Const WM_GETTEXT = &HD'获取文本框内容的消息

   Public Const GWL_WNDPROC (-4)'建立一个消息处理函数需要的参数

   public OldProc as long'保存旧的消息处理函数的地址

3. 在窗体上建立一个文本框,一个命令按钮,两个检查框修改其属性如下:

   控件名称:    属性:    属性值:

       文本框   Passwordchar     *

            名称         text1

       命令按钮  名称         command1

            caption       真正的密码

       检查框1   名称         check1

            caption       使用密码保护

       检查框1   名称         check2

            caption       使用密码欺骗

            

4. 编写代码(程序很简单)

Form1中加入以下代码:

Private Sub Check1_Click()

If Check1.Value = 1 Then

  Oldproc = SetWindowLong(Text1.hwnd, GWL_WNDPROC, AddressOf wnd)'设置Text1的消息处理函数,Oldproc为原来函数的地址

  Else

 SetWindowLong Text1.hwnd, GWL_WNDPROC, Oldproc'恢复原来的消息函数地址

 check2.value=0   '如果不使用密码保护则不能使用密码欺骗

End If

End Sub

Private Sub Check2_Click()

If Check2.Value = 1 Then

  if check1.value=0 then'如果使用密码欺骗必须使用密码保护

   Oldproc = SetWindowLong(Text1.hwnd, GWL_WNDPROC, AddressOf wnd)

   Check1.Value = 1

  end if

End If

End Sub

Private Sub Command1_Click()

  MsgBox Text1.Text'真正文本框中的内容

End Sub

Private Sub Form_Unload(Cancel As Integer)

  SetWindowLong Text1.hwnd, GWL_WNDPROC, Oldproc'恢复原来的消息处理函数地址

End Sub

 在模块中加入消息处理函数:

Public Function wnd(ByVal hwnd As Long, ByVal Msg As Long, ByVal wp As Long, ByVal lp As Long) As Long

 ' hwnd 接收消息的控件,这里是Text1,msg消息类型,wp和lp为附加参数参数

If Msg = WM_GetText Then'判断是否是我们要的消息

 If Form1.Check2.Value = 1 Then'是否进行欺骗

  hwnd = Form1.Check2.hwnd

  '更改接收消息的对象这里我们改成Check2,那么得到的就是check2的Caption值,给那些盗密码者一点教训,让他们回去试密码吧:)

 Else

  Exit Function'不做任何处理,直接返回

End If

End If

wnd = CallWindowProc(Oldproc, hwnd, Msg, wp, lp)'如果不是我们要的消息则传递下去

End Function

到此程序就结束了,运行结果如图1所示,调出来一个查"*"的程序查查看,当你不选“使用密码保护”的时候文本框的内容会被得到。选中后再试试,怎么样,是不是什么也得不到,然后在选中“使用密码欺骗"试一下得到的是什么 :)。

密码最终会被破解。记住是“最终”(如果你的密码够长,谁知道是多少年以后)

本程序在:VB6.0 Windows me 下调试通过

如有不懂得地方或讨论问题可以给我发邮件:ppgg2002@sina.com

QQ:55051552

我来说两句】 【加入收藏】 【返加顶部】 【打印本页】 【关闭窗口
中搜索 让你的文本框“聪明”一点
本类热点文章
  揭穿号称内存占用极低的软件的诡计
  用VB6实现真正实用的多线程处理
  读写INI文件的四个函数
  shell函数能以同步方式打开一个exe文件
  VB的API编程精粹
  TAPI笔记
  锁定计算机
  巧用API函数增强VB位操作功能
  在VB中使用API函数
  让你的文本框“聪明”一点
  关机消息的拦截
  在WIN2000下实现程序的关机
最新分类信息我要发布 
最新招聘信息

关于我们 / 合作推广 / 给我留言 / 版权举报 / 意见建议 / 广告投放  
Copyright ©2003-2019 Lihuasoft.net webmaster(at)lihuasoft.net
网站编程QQ群   京ICP备05001064号 页面生成时间:0.00341