网页功能: 加入收藏 设为首页 网站搜索  
DataGrid 控件的使用
发表日期:2006-08-10作者:[转贴] 出处:  

使用 DataGrid 控件

    DataGrid 控件是一种类似于电子数据表的绑定控件,可以显示一系列行和列来表示 Recordset 对象的记录和字段。可以使用 DataGrid 来创建一个允许最终用户阅读和写入到绝大多数数据库的应用程序。DataGrid 控件可以在设计时快速进行配置,只需少量代码或无需代码。当在设计时设置了DataGrid 控件的 DataSource 属性后,就会用数据源的记录集来自动填充该控件,以及自动设置该控件的列标头。然后您就可以编辑该网格的列;删除、重新安排、添加列标头、或者调整任意一列的宽度。
    在运行时,可以在程序中切换 DataSource 来察看不同的表,或者可以修改当前数据库的查询,以返回一个不同的记录集合。
    注意 DataGrid 控件与 Visual Basic 5.0中的 DBGrid 是代码兼容的,除了一个例外:DataGrid 控件不支持 DBGrid 的“解除绑定模式”概念。DBGrid 控件包括在 Visual Basic 的 Tools 目录中。

    可能的用法
    查看和编辑在远程或本地数据库中的数据。
    与另一个数据绑定的控件(诸如 DataList 控件)联合使用,使用 DataGrid控件来显示一个表的记录,这个表通过一个公共字段链接到由第二个数据绑定控件所显示的表。

    使用 DataGrid 控件的设计时特性
    可以不编写任何代码,只通过使用 DataGrid 控件的设计时特性来创建一个数据库应用程序。下面的说明概要地说明了在实现 DataGrid 控件的典型应用时的一般步骤。完整的循序渐进的指示,请参阅主题“DataGrid 方案1: 使用 DataGrid 控件创建一个简单数据库应用程序”。
要在设计时实现一个 DataGrid 控件
    1. 为要访问的数据库创建一个 Microsoft 数据链接 (.MDL) 文件。请参阅“创建 Northwind OLE DB 数据链接”主题,以获得一个示例。
    2. 在窗体上放置一个 ADO Data 控件,并将其 ConnectionString 属性设置为在第 1 步中所创建的OLE DB 数据源。
    3. 在这个 Ado Data 控件的 RecordSource 属性中输入一条将返回一个记
录集的 SQL 语句。例如,Select * From MyTableName Where CustID = 12
    4. 在窗体上放置一个 DataGrid 控件,并将其 DataSource 属性设置为这个 ADO Data 控件。
    5. 右键单击该 DataGrid 控件,然后单击“检索字段”。
    6. 右键单击该 DataGrid 控件,然后单击“编辑”。
    7. 重新设置该网格的大小、删除或添加网格的列。
    8. 右键单击该 DataGrid 控件,然后单击“属性”。
    9. 使用“属性页”对话框来设置该控件的适当的属性,将该网格配置为所需的外观和行为。

    在运行时更改显示的数据
    在创建了一个使用设计时特性的网格后,也可以在运行时动态地更改该网格的数据源。下面介绍实现这一功能的通常方法。

    更改 DataSource 的RecordSource
    更改所显示的数据的最通常方法是改变该 DataSource 的查询。例如,如果DataGrid 控件使用一个ADO Data控件作为其 DataSource,则重写RecordSource和刷新该ADO Data 控件都将改变所显示的数据。
    ' ADO Data 控件连接的是 Northwind 数据库的' Products 表。新查询查找所有
    ' SupplierID = 12 的记录。
    Dim strQuery As String
    strQuery = "SELECT * FROM Suppliers WHERE SupplierID = 12"
    Adodc1.RecordSource = strQuery
    Adodc1.Refresh

    更改 DataSource
    在运行时,可以将 DataSource 属性重新设置为一个不同的数据源。例如,您可能具有若干个 ADO Data 控件,每个控件连接不同的数据库,或设置为不同的 RecordSource 属性。可以简单地将 DataSource 从一个 ADO Data控件重新设置为另一个 ADO Data 控件:
    ' 将 DataSource 重新设置为一个连接到 Pubs 数据库的、
    ' 使用 Authors 表的 ADO Data 控件。
    Set DataGrid1.DataSource = adoPubsAuthors

    重新绑定 DataSource
    当将 DataGrid 控件用于一个远程数据库,诸如 SQLServer 时,可以改变表的结构。例如,可以给这个表添加一个字段。在这种情形下,可以调用Rebind 方法根据新的结构来重新创建该网格。注意,如果已经在设计时改变了这个列的布局,DataGrid 控件将会试图重新创建当前的布局,包括任何空的列。不过,通过首先调用 ClearFields 方法,可以强制该网格重新设置所有的列。

    从 DataGrid 返回值
    在 DataGrid 被连接到一个数据库后,可能想要监视用户单击了哪一个单元。可以使用 RowColChange 事件——而不是 Click 事件。如下所示:
    Private Sub DataGrid1_RowColChange(LastRow As Variant, ByVal LastCol As Integer)
       ' 显示用户所单击的单元的文字、行和列的信息。
       Debug.Print DataGrid1.Text; DataGrid1.Row; DataGrid1.Col
    End Sub

    使用 CellText 和 CellValue 方法
    当一个列使用 NumberFormat 属性设置格式后,CellText 和 CellValue 属性是很有用的。NumberFormat 属性不必更改实际的数据格式就可以更改任何包含数字的列的格式。例如,给定一个网格,其中包含一个名为 ProductID的、包含整数的列。下面的代码将使 DataGrid 以"P-0000" 的格式来显示数据。换句话说,尽管在 ProductID 字段中所包含的实际数值为 "3",但该网格所显示的值将是 "P-0003"。
      Private Sub Form_Load()
        DataGrid1.Columns("ProductID").NumberFormat = "P-0000"
      End Sub
    要返回数据库中所包含的实际值,应使用 CellValue 方法,如下所示:
      Private Sub DataGrid1_RowColChange(LastRow As Variant, ByVal LastCol As Integer)
        Debug.Print _
        DataGrid1.Columns("ProductID").CellValue(DataGrid1.Bookmark)
      End Sub
    注意 上面所用的 CellValue 和下面所用的 CellText 值,都需要将Bookmark 属性作为一个参数,功能才正确。
    相反地,如果要返回该字段的格式化的值,应使用 CellText 方法:
      Private Sub DataGrid1_RowColChange(LastRow As Variant, ByVal LastCol As Integer)
        Debug.Print _
        DataGrid1.Columns("ProductID").CellText(DataGrid1.Bookmark)
      End Sub
    注意 上面的 CellText 方法等价于使用 DataGrid 控件的 Text 属性。

    下一步
    要阅读关于使用该控件创建简单的应用程序的一个循序渐进的过程,请参阅“使用 DataGrid 控件创建简单的数据库应用程序”,或“创建一个连接DataList 控件的 DataGrid”。
    要了解关于 Split 对象以及如何对其编程的详细信息,请参阅“操作DataGrid 视图”。

    创建 Northwind 的OLE DB 数据链接
    访问数据的一个重要步骤是为想要访问的每个数据库都创建一个 OLE DB数据源。下面的步骤为 Visual Basic 所提供的Nwind.mdb (Northwind) 数据库创建这样一个对象。这个数据源被用于 Visual Basic 文档所提供的一些示例过程。在一个计算机上只需要创建一次OLE DB数据源。

    要创建 Northwind 的OLE DB 数据源
    1. 打开 Windows Explorer或 Windows NT Explorer。
    2. 打开您想要创建 OLE DB 数据源的目录。在该示例中,打开 ProgramFiles、Microsoft Visual Studio和VB98。
    3. 右键单击 Explorer 的右边窗格,然后单击上下文菜单上的“新建”。从文件类型列表中单击“Microsoft 数据链接”。
    4. 重命名新文件 Northwind.MDL。
    5. 右键单击文件并单击上下文菜单上的“属性”,以显示“Northwind.MDLProperties”对话框。
    6. 单击“连接”选项卡。
    7. 单击“提供方”框并选择“Microsoft Jet 3.51 OLE DB Provider”。
    8. 在Data Source 框中输入nwind.mdb文件的路径。
    9. 单击“测试连接”,检测连接。
    10. 如果连接通过,单击“确定”。
    注意 也可以通过在“控制面板”中单击“数据链接”图标创建一个 OLE DB数据源。在“管理数据链接文件”对话框中,单击“新建”创建一个新的数据源。

    使用 DataGrid 和 ADO Data控件创建一个简单的数据库应用程序
    只使用一个 DataGrid 和一个 ADO Data 控件,可以创建一个允许最终用户阅读和写入记录集的数据库应用程序。

    要使用 ADO 数据控件来创建一个简单的数据库应用程序
    1. 为 Northwind 数据库创建一个OLE DB 数据源。如果还没有创建数据源,请按照“创建 Northwind 的OLE DB Data Link”中的步骤操作。
    2. 在Visual Basic 中创建一个新的标准的 EXE 工程。如果 DataGrid 控件不在“工具箱”中,则用右键单击“工具箱”,然后使用“部件”对话框来添加控件。同时也载入 ADO 控件。
    3. 在空窗体上各放置控件的一个实例。
    4. 将 ADO 控件的ConnectionString 属性设置为 Northwind 的数据源。单击并选定该 ADO Data 控件,并按 F4 键出现“属性”窗口。单击“ConnectionString”,然后单击 OLE DB File。单击 Northwind 的数据源。
    5. 设置 ADO 控件的 RecordSource 属性。在“属性”窗口中,单击“记录源”并输入一条 SQL 语句来填充 DataGrid
控件。在本例中,输入“Select * From Products”。
    6. 将 DataGrid 控件的 DataSource 属性设置为这个 ADO Data 控件。单击并选定该 DataGrid 控件。在其“属性”窗口中,单击“数据源”将出现一个包含所有数据控件的下拉列表——在本例中只有 ADO Data 控件。单击这个控件。
    7. 按 F5 键运行这个工程。

    创建一个连接 DataList 控件的 DataGridData
    Grid 的通常用法是显示数据库的一个表所提供的“详细内容”。例如,Northwind (Nwind.mdb) 数据库包括两个表,一个名为 "Suppliers",另一个名为 "Products"。在本例中,我们使用 DataList 控件来显示 "Suppliers" 表中的供应商的公司名称。当用户单击任意一个公司名称时,这个 DataList 控件将提供该公司的 SupplierID。使用这个标识符,就可以构造一个查询,在 "Products" 表中检索具有相匹配的 SupplierID 的所有记录。换句话说,当用户单击一个公司时(在 DataList 控件中),该公司生产的所有产品将出现在 DataGrid 控件中。
要使用一个指定供应商的产品填充一个 DataGrid 控件
    1. 确认在机器上已为 Northwind 数据库建立了一个OLE DB 数据源;如果还没有创建这样的一个数据源,请按照“创建 Northwind 的OLE DBData连接”的步骤操作。
    2. 在Visual Basic 中创建一个新的标准的 EXE 工程。
    如果 DataGrid、DataList 和 ADO Data 控件不在“工具箱”中,则右键单击“工具箱”,然后单击“部件”。在“部件”对话框中双击“MicrosoftDataGrid Control”、“Microsoft DataList Controls”以及“Microsoft ADOControl”。
    3. 在一个空窗体中各放置一个 DataGrid 和 DataList 控件的实例。将 DataList 控件放置在该窗体的左上角,然后将 DataGrid 控件放在它的下面的某处。
    4. 在窗体放置两个 ADO Data 控件实例。选择第一个 ADO Data 控件,并按 F4 键来显示其“属性页”。将该控件的 Name 属性设置为 adoSuppliers。选择第二个 ADO Data 控件并将其 Name 属性设置为 adoProducts。将第一个控件直接放在 DataList 控件的下面,把第二个控件直接放在 DataGrid 控件的下面。
    5. 将这两个 ADO Data 控件的 ConnectionString 属性设置为 Northwind的OLE DB 数据源。选择名为 adoSuppliers 的控件,然后将其ConnectionString 属性设置为Northwind 的OLE DB data source (Northwind.mdl)。选择名为 adoProducts的控件,并重复该操作。
    6. 设置这两个 ADO Data 控件的 RecordSource 属性。选择 adoSuppliers 并在其“属性页”上单击“RecordSoure”。输入 Select* From Suppliers。这个查询将指示该 ADO Data 控件返回 Suppliers 表中的所有记录。选择 adoProducts,单击“RecordSoure”,并输入 Select *From Products。这个查询将返回在 Products 表中的所有记录。
    7. 将 DataList 控件的 RowSource 属性设置为 adoSuppliers。
     RowSource 属性决定由哪一个数据源为 ListField 属性供应数据。
    8. 将 DataList 控件的 ListField 属性设置为 CompanyName。
     ListField 属性被设置成名为 Suppliers 的表中的字段名称。在运行时,DataList 控件显示在这个属性中所指定的字段的值。在本例中,该属性将显示在 Suppliers 表中找到的一个公司名称。
    9. 将 DataList 控件的 BoundColumn 属性设置为 SupplierID。
     BoundColumn 属性被设为 Suppliers 表中的第二个字段。在本例中,这个属性就被设为 SupplierID 字段。当单击 DataList 控件时,BoundText属性返回与在 DataList 控件中所显示的公司相关联的 SupplierID 字段的值。这个值将用于对 Products 表的查询,该查询为 DataGrid 控件提供数据。
    10. 将 DataGrid 控件的 DataSource 属性设置为 adoProducts。
     DataSource 属性为该控件指定数据源。在本例中,该属性被设置为名为adoProducts 的 ADO Data 控件,这将返回 Products 表中的所有记录。
    11. 在窗体的代码模块中,添加下述内容:
      Private Sub Datalist1_Click()
      ' 声明一个用来包含新查询的字符串变量。这个新的
      ' 查询使用 DataList 控件的BoundText属性
      ' 来提供一个 SupplierID 值。新查询查找所有
      ' 具有相同的 SupplierID 的产品。这个查询被
      ' 指定给名为 adoProducts 的 ADO Data 控件
      ' 的 RecordSource 属性。在刷新控件后,DataGrid
      ' 将使用包含由同一个公司供应的所有产品的新
      ' 记录集来更新。

      Dim strQuery As String
      strQuery = "Select * FROM Products WHERE SupplierID = " & _
      Datalist1.BoundText

      With adoProducts
        .RecordSource = strQuery
        .Refresh
      End With

      With DataGrid1
        .ClearFields
        .ReBind
      End With
      End Sub
    12. 运行该工程。
    单击 DataList 控件中的任意公司名称,将自动用该公司所供应的产品更新 DataGrid 控件。


    使用列
    通过更改 DataSource 属性,可以动态地更改在 DataGrid 控件中显示的数据。例如,可以显示同一个数据库的不同表。如果这样做,则 DataGrid 控件将只根据默认的属性显示数据。

    添加、删除或隐藏列
    通过使用 Columns 集合和 Column 对象的属性和方法,可以在程序中添加、删除或隐藏列。

    添加和删除一列
    要在运行时添加一列,可以使用 Add 方法。如果首先声明一个变量,并将新对象赋给该变量,就可以用简明的代码设置各种属性。
    Private Sub AddColumn()
      ' 在最右边的位置添加一列。然后设置其 Visible、Width、
      ' Caption以及 Alignment 属性。DataField 属性则指定
      ' 该列将绑定到哪一个字段。
      Dim c As Column
      Set c = DataGrid1.Columns.Add(DataGrid1.Columns.Count)
      With c
       .Visible = True
       .Width = 1000
       .Caption = "我的新列"
       .DataField = Adodc1.Recordset.Fields("ProductName").Name
       .Alignment = dbgRight
      End With
    End Sub
    可以使用方法来删除任意一列。请确保使用 ColIndex 参数来指定要删除的列。下面的代码将删除被单击的列。
    Private Sub DataGrid1_HeadClick(ByVal ColIndex As Integer)
       DataGrid1.Columns.Remove ColIndex
    End Sub

    隐藏一列
    通过将 Visible 属性设置为 False,可以隐藏任意一列。当想要限制用户可以查看或编辑的列时这一功能特别有用。下面的示例在 Columns 集合中循环,隐藏除少数列之外的所有列。
    Private Sub HideColumns()
      ' 使用 DataField 属性来判别正在测试的是哪一列。
      ' 只显示三列:ProductName、UnitPrice以及
      ' UnitsInStock。
      Dim c As Column
      For Each c In DataGrid1.Columns
         Select Case c.DataField
         Case "ProductName"
           c.Visible = True
         Case "UnitPrice"
           c.Visible = True
         Case "UnitsInStock"
           c.Visible = True
           c.Caption = "In Stock"    ' 更改这个列的标头。
         Case Else             ' 隐藏其它所有的列。
           c.Visible = False
         End Select
      Next c
    End Sub

    操作 DataGrid 视图
    一个“拆分”的网格使最终用户对相同的数据可以拥有多个视图。例如,假设有一个由十个字段组成的大表。在这种情况下,在控件中察看的记录集将有十列宽,除非窗体非常宽,否则用户将无法同时看见所有列的内容。,而且,假设用户只对第一列和最后一列感兴趣(例如,第一列是名字,最后一列是电话号码)。为了能同时看到在两端的列(不重新安排列的顺序),可以对网格进行拆分。

    创建一个 Split 对象
    在设计时,可以创建一个拆分,具体步骤是:右键单击网格,单击“编辑”,再单击右键,然后单击“拆分”。通过右键单击该控件,并单击“属性”来显示“属性页”对话框,可以编辑这个拆分。可以使用“拆分”选项卡来自定义拆分。要删除一个拆分,右键单击该拆分,并单击“删除”。
    在运行时,最终用户也可以通过单击位于这个网格控件的左下边的右边的选项卡,以手工方式来拆分该网格(除非不允许这个操作),如下图所示:

默认情况下,DataGrid 控件包含一个 Split 对象。防止最终用户添加拆分的代码为:
    DataGrid1.Splits(0).AllowSizing = False

    在程序中添加和删除拆分
    DataGrid 控件包含一个 Split 对象的集合。要在程序中添加拆分,可以使用 Add 方法,如下所示:
    DataGrid1.Splits.Add 1
    注意 Add 方法需要新的拆分索引作为其参数。要添加一个拆分,应将这个索引参数设置为 Splits 集合的 Count 属性值。
    使用 Split 集合的 Add 方法,可以在程序中按照实际需要添加拆分。由于添加多于两个以上的拆分将使网格很难使用,可以使用该集合的 Count 属性来限制拆分的数目。
    If DataGrid1.Splits.Count < 3 Then ' 添加一个拆分。
       DataGrid1.Splits.Add DataGrid1.Splits.Count
    End If

    使拆分同步
    当拆分多于一个时,可能希望控制这些拆分如何滚动。例如,在一个具有三个拆分的网格中,可以决定只让第一个和第三个拆分同步,而让中间的拆分独立地滚动。要同步任何两个(或多个)拆分,只需将每个 Split 对象的 ScrollGroup 属性设置为同一个值。
    ' 使第一个和第三个 Split 对象同步。
    With DataGrid1
      .Splits(0)
    .ScrollGroup = 1
    .Splits(1).ScrollGroup = 2
    .Splits(2).ScrollGroup = 1
    End With
    通过设置 Scrollbars 属性,使同步的拆分组只显示一个滚卷条,从而进一步自定义拆分的外观。

    控制 Tab 键和箭头键的行为
    使用 WrapCellPointer、TabAcrossSplits以及 TabAction 属性,可以决定当最终用户按下 tab 键或箭头键时网格的行为。
    在这三个属性中,TabAction 属性级别最高,它决定 WrapCellPointer 和TabAcrossSplits 这两个属性是否能生效。TabAction 有三个设置值: ControlNavigation、Column Navigation 和 Grid Navigation。当该属性设置为 ControlNavigation 时,按 Tab 键根据 TabIndex 将焦点切换到下一个控件。这一设置优先于 WrapCellPointer 和 TabAcrossSplits。
    WrapCellPointer 属性决定在任何单个的拆分中 tab 键和箭头键的行为。如果该属性设置为 True,且当前单元位于最后一列,这时最终用户按 tab 键则使第一列的下一行变成当前的单元。不过,如果当前单元位于最后一行的最后一列时,这时就没有地方可以“换行”。
    TabAcrossSplits 属性决定当网格中存在两个或多个拆分时 tab 和箭头键的行为。如果该属性设置为 True,且当前单元位于任何一个拆分的最后一列,则按Tab或箭头键将使当前单元“跳” 到下一个拆分的第一列。当前单元仍保持相同的行位置。
    注意 如果 WrapCellPointer 和 TabAcrossSplits 属性都设置为 True,则只有当前单元位于最后一个拆分的最后一列时才会换行。这时当前单元将换到第一个拆分的第一列中的下一行。

    自定义列集合
    每一个 Split 对象都有一个 Columns 属性,允许用户来操作一个 Column对象的集合。通过这样做,可以更改每个 Split 对象的外观。例如,可以用一个拆分包含显示姓氏字段和名字字段的两个列,而第二个拆分则显示电话字段和地址字段。要实现这一目标,需要将其它的每一列的 Visible 属性设置为 False,如下所示:
    ' 枚举 Columns 集合,对每一个 Column 对象的 DataField 属性
    ' 进行测试。如果测试失败,则隐藏这一列。
    Dim i As Integer

    ' 隐藏除 ProductName 列之外的所有列。
    For i = 0 To DataGrid1.Splits(0).Columns.Count - 1
      If DataGrid1.Splits(0).Columns(i).DataField <> "ProductName" Then
         DataGrid1.Splits(0).Columns(i).Visible = False
      End If
    Next i

    ' 隐藏除 UnitPrice 列之外的所有列。
    For i = 0 To DataGrid1.Splits(0).Columns.Count - 1
      If DataGrid1.Splits(1).Columns(i).DataField <> "UnitPrice" Then
         DataGrid1.Splits(1).Columns(i).Visible = False
      End If
    Next I

   使用 Bookmarks 和 SelBookmarks 跟踪记录
    Bookmarks 和 SelBookmarks 提供了标记记录的一种手段。当编写应用程序中的特定功能(诸如允许最终用户手工地选择多个不相邻的记录,进行所选记录的大批更新)时,这就很有必要。在这些情形中,需要标记哪些记录已被选择,因此可以使用 SelBookmarks 集合及其属性。
    有两个函数,分别是 CellText 和 CellValue 方法,需要标记才能正确执行。

    标记用户的选择
    SelBookmarks 集合包含所有选定的记录的书签。当最终用户手工选择记录时(即在单击时按住 CTRL 键),每一个选定的记录的书签都会加入到该集合中。使用标准的循环,用户可以知道已经选定了什么,也可以保存书签(因为可能需要恢复某个值),以及执行操作:
    Dim i as Integer ' 计数器
    Dim intCount As Integer
    intCount = DataGrid1.SelBookmarks.Count - 1
    ReDim arrSelBK(intCount) ' 声明用于保存书签的数组。
    For i = 0 To intCount
      ArrSelBK(i) = DataGrid1.SelBookmarks(i)
      ' 在此处执行操作。如果该操作必须被
      ' 取消,则退出该循环,然后使用该数
      ' 组来取消这些更改。
    Next i

    通过在程序中添加到 SelBookmarks 集合来选择记录
    通过将记录添加到这个集合,也可以在程序中选定记录。例如,可能有一个显示指定的客户所有订货的网格。如果要高亮显示该客户花费超过 $100的所有记录,则对记录进行过滤,并将结果书签添加到 SelBookmarks 集合。
    Dim rs As Recordset
    Set rs = Adodc1.Recordset

    While Not rs.EOF
      If rs!SupplierID = 12 Then
        DataGrid1.SelBookmarks.Add rs.Bookmark
      End If
      rs.MoveNext
    Wend

    显示计算结果字段
    假设在表中有一个名为 "Price" 的字段,并且想使用本地税率来计算表中每一项的税费。这就是一个计算结果字段,可以通过修改 DataSource 的查询来计算这个值,并把这个值返回给 DataGrid 控件。
    要在 DataGrid 控件中创建一个计算结果字段
    1. 确认在机器上已为 Northwind 数据库建立了一个OLE DB 数据源;如果还没有创建这样的一个数据源,请按照“创建 Northwind 的OLE DBData 连接”的步骤操作。
    2. 在窗体上放置一个 ADO Data 控件和一个 DataGrid 控件。
    3. 将 ADO Data 控件的ConnectionString 属性设置为 Northwind 的数据源。
    4. 设置 ADO Data 控件的 RecordSource 属性。在“属性”窗口中,单击“记录源”并输入 Select ProductName, UnitPrice,(UnitPrice * .082) As Tax From Products。
    5. 将 DataGrid 控件的 DataSource 属性设置为这个 ADO Data 控件。
    6. 运行该工程。

    与类模块一起使用 DataGrid 控件
    如果想要访问以自定义格式或以 ODBC 驱动程序不直接支持的格式存放的数据,可以创建一个类来封装该数据。然后可以编写该类的自定义函数来检索这些数据。这样该类就变成了一种数据源,可以被任何数据使用者(如DataGrid 控件)使用。
    在这个类模块的Initialize 事件中,首先通过声明一个作为 New ADODB.Recordset的变量,来创建一个 ADODB recordset 对象。在创建了这个 recordset 对象后,再添加字段,每个数据源中的每个字段都要加入。然后使用合适的数据填充这个记录集。
    注意 也可以使用 OLEDB 示例提供者来创建一个数据源。关于 OLEDB示例提供者的详细信息,请参阅“创建带有数据提供方的部件”。
    类模块有一个 GetDataMember 事件,只要当数据使用者(诸如 DataGrid 控件)需要数据时就产生该事件。在这个事件中,Data 参数被设置为在Initialize 事件中所创建的 recordset 对象。
    如果要使用这个类模块,应创建一个具有一个 DataGrid 控件的窗体。在该窗体的 Load 事件的代码中,将该控件的 DataSource 属性设置为这个类。
    注意 数据类模块在设计时是不可用的。例如,如果使用 DataGrid 控件,则当用户在“属性”窗口中单击“数据源”时,所有可用的数据源都会出现在一个下拉列表中。但其中不会有这个数据类模块,它只能在代码中设置。

    使用类模块创建一个数据源
    下面的示例使用一个类模块来创建一个简单数据源。然后通过 DataSource属性将 DataGrid 控件绑定到该模块。
要创建一个用于DataGrid 的类
    1. 创建一个新的标准 Exe 工程。
    2. 给窗体添加一个 DataGrid 控件。如果DataGrid控件不在“工具箱”中,则在“工程”菜单中单击“部件”,
再单击“Microsoft DataGrid Control”,然后单击“确定”。
    3. 在“工程”菜单中,单击“引用”。在“引用”对话框中,单击“MicrosoftActiveX Data Objects 2.0 Library”。
    4. 在“工程”菜单中,单击“添加类模块”来给工程添加一个数据类模块。
    5. 在“工程资源管理器”窗口中,单击并选定“类”图标,并按 F4 键显示“属性”窗口。
    6. 在“属性”窗口中,将类的名称更改为NamesData。
    7. 在“属性”窗口中,单击“DataSourceBehavior”并将该属性更改为vbDataSource。
    8. 在该类模块的 Declarations 部分,创建一个 ADODB Recordset变量,如下所示:
    Option Explicit
    Private WithEvents rsNames As ADODB.RecordSet
    使用 WithEvents 关键词来声明该变量,使用户可以对 RecordSet 对象的事件编程。
    9. 在该类的 Initialize 事件中,添加下述代码:
    Private Sub Class_Initialize()
      ' 将新的数据成员的名称添加到 DataMember 集合
      ' 这使其它对象可以看见这些可用的
      DataMembersDataMembers.Add "Names"

      Set rsNames = New ADODB.RecordSet    ' 设置对象变量。
      ' 创建一个具有两个字段的 recordset,并打开该 recordset。
      ' 第一个记录具有一个整数的数据类型,第二个记录是一个最大可
      ' 达 256 个字符的字符串。CursorType 被设置为 OpenStatic
      ' —— 一个可更新的对一组记录的快照。LockType 被设置为
      ' LockOptimistic,以允许对该 recordset 进行更新。
      With rsNames
        .Fields.Append "ID", adInteger
        .Fields.Append "Name", adBSTR, 255
        .CursorType = adOpenStatic
        .LockType = adLockOptimistic
        .Open
      End With

      Dim i As Integer
      For i = 1 to 10   ' 添加十条记录。
        rsNames.AddNew
        rsNames!ID = i
        rsNames!Name = "Name " & i
        rsNames.Update
      Next i
      rsNames.MoveFirst ' 移到该记录集的开始。
    End Sub
    这部分代码首先创建 recordset 对象,然后给该对象添加两个字段。代码接着给 recordset 添加十条记录。
    10. 在该类的 GetDataMember 事件中,添加下述代码 :
    Private Sub Class_GetDataMember(ByVal DataMember As String, _
    Data As Object)
       Set Data = rsNames
    End Sub
    只要发生该事件——即当该类对象被绑定到一个数据使用者,如 DataGrid控件时,代码将返回该 recordset 对象。
    11. 在 Form 对象的代码模块中,声明一个数据类的对象变量:
    Option Explicit
    Private datNames As NamesData ' 类变量
    12. 在 Form 对象的 Load 事件的代码中,将 DataGrid 控件的 DataSource设置为该类对象。
     Private Sub Form_Load()
       ' 创建一个新的 NamesData 对象
       Set datNames = New NamesData
       ' 将这个 DataGrid 绑定到新的数据源 datNames
       Set DataGrid1.DataSource = datNames
     End Sub
    13. 按 F5 键运行该工程。

    RecordSet事件的编程
    也可以对这个 Recordset 对象的事件进行编程。在该类模块中,单击“对象”框(在位于左上角),然后单击“rsNames”。在“过程/事件”框(在右上角)中,下拉列表将显示这个 Recordset 对象的所有事件。

    给类添加一个属性
    类模块也可以进行修改,来响应事件或函数调用。下面的代码演示了如何先给类添加属性。当从其它对象调用该对象时,这一属性将返回该类的RecordCount。
    Public Property Get RecordCount() As Long
       RecordCount = rsNames.RecordCount
    End Sub

    使用 DataMember 属性
    GetDataMember 事件也包括 DataMember 参数。使用这个参数,可以在类模块中包括多个记录集,并使用带 DataMember 参数的 Select Case 语句来返回相应的记录集:
    Private Sub Class_GetDataMember(ByVal DataMember As String, Data As _
    Object)
       Select Case DataMember
       Case "Names"
         Set Data = rsNames
       Case "Dates"
         Set Data = rsDates
       Case Else
         ' 设置一个默认的数据成员
         Set Data = rsYears
       End Select
    End Sub
    如果要指定所需的 DataMember,请将数据使用者的 DataMember 属性设置为适当的字符串,然后如平常一样设置 DataSource。对于 DataGrid 控件,可以采用如下方法:
    Private Sub Form_Load()
       ' 创建一个新的 NamesData 对象
       Set datNames = New NamesData
       ' 指定所需的 DataMember,然后设置 DataSource。
       DataGrid1.DataMember = "Names"
       Set DataGrid1.DataSource = datNames
    End Sub

我来说两句】 【加入收藏】 【返加顶部】 【打印本页】 【关闭窗口
中搜索 DataGrid 控件的使用
本类热点文章
  在VB应用程序中调用Excel2000
  在VB中使用水晶报表的一种简易编程方法
  BOM表查询的VB实现方法
  如何將Excel的文件导入Access文件
  把DataGrid的数据快速写入EXCEL
  Visual Basic 导出到 Excel 提速之法
  DataGrid 控件的使用
  VB中DataCombo和DataList 控件的使用
  ADO三大对象的属性、方法、事件及常数
  VB中MSHFlexGrid控件的应用
  VB+ADO检测数据库并发操作和处理并解决..
  用VB+WORD模版+数据库来制作格式合同..
最新分类信息我要发布 
最新招聘信息

关于我们 / 合作推广 / 给我留言 / 版权举报 / 意见建议 / 广告投放  
Copyright ©2003-2018 Lihuasoft.net webmaster(at)lihuasoft.net
网站编程QQ群   京ICP备05001064号 页面生成时间:0.00423